Contract Address Details

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "./PoolManager.sol";
import "./MatchManager.sol";
import "./PrizeManager.sol";

contract GamiFi is Ownable, PoolManager, MatchManager, PrizeManager {
    using SafeERC20 for IERC20;

    constructor() Ownable(msg.sender) {}

    function createPool(
        bytes32 poolId,
        address tokenAddress
    ) public onlyOwner returns (address) {
        return _createPool(poolId, tokenAddress);
    }

    function setPoolState(
        bytes32 poolId,
        PoolState newState
    ) public override onlyOwner {
        super.setPoolState(poolId, newState);
    }

    function createMatch(
        bytes32[] memory poolIds
    ) public onlyOwner returns (bytes32[] memory) {
        require(poolIds.length >= 2, "At least 2 pools required");
        require(poolIds.length % 2 == 0, "Pool array length must be even");

        bytes32[] memory matchIds = new bytes32[](poolIds.length / 2);

        for (uint256 i = 0; i < poolIds.length; i += 2) {
            bytes32 poolA = poolIds[i];
            bytes32 poolB = poolIds[i + 1];

            Pool storage _poolA = pools[poolA];
            Pool storage _poolB = pools[poolB];
            require(_poolA.isActive, "Token pool A does not exist");
            require(_poolB.isActive, "Token pool B does not exist");
            require(_poolA.matchId == bytes32(0), "Pool A already in a match");
            require(_poolB.matchId == bytes32(0), "Pool B already in a match");
            require(poolA != poolB, "Pools must be different");

            // Set pool state to match in progress
            bytes32 matchId = _createMatch(poolA, poolB);
            _matchPools(poolA, poolB, matchId);
            _startMatch(poolA, poolB);

            // Disable deposits and withdrawals during match
            pools[poolA].isDepositAllowed = false;
            pools[poolA].isWithdrawalAllowed = false;
            pools[poolB].isDepositAllowed = false;
            pools[poolB].isWithdrawalAllowed = false;

            matchIds[i / 2] = matchId;
        }

        return matchIds;
    }

    function endMatch(
        bytes32 poolA,
        bytes32 poolB,
        bytes32 winner,
        address[] memory players,
        uint256[] memory shares
    ) public override onlyOwner {
        // Set pool state to match ended
        setPoolState(poolA, PoolState.MATCH_ENDED);
        setPoolState(poolB, PoolState.MATCH_ENDED);

        bytes32 matchId = getMatchId(poolA, poolB);
        super.endMatch(poolA, poolB, winner, players, shares);

        bytes32 _losingToken = getLoser(poolA, poolB);
        uint256 _losingTokenBalance = pools[_losingToken].totalFunds;

        uint256 _serviceFee = _claimServiceFee(
            matchId,
            pools[_losingToken].tokenAddress,
            _losingTokenBalance
        );
        _claimFunds(_losingToken, _serviceFee);
    }

    function claimPrize(bytes32 poolA, bytes32 poolB) public nonReentrant {
        bytes32 matchId = getMatchId(poolA, poolB);
        Match storage _match = matches[matchId];
        require(_match.state == MatchState.MATCH_ENDED, "Match is not over");

        bytes32 _winningToken = _match.winner;
        bytes32 _losingToken = getLoser(poolA, poolB);
        uint256 _losingTokenInitialBalance = pools[_losingToken].totalFunds;
        uint256 _playerSharePercentage = getPlayerShare(
            poolA,
            poolB,
            msg.sender
        );
        uint256 _stakerSharePercentage = getStakerShare(
            _winningToken,
            msg.sender
        );
        uint256 _stakerContribution = getContribution(
            _winningToken,
            msg.sender
        );

        (
            uint256 _claimedWinningToken,
            uint256 _claimedLosingToken
        ) = _claimPrize(
                matchId,
                pools[_winningToken].tokenAddress,
                pools[_losingToken].tokenAddress,
                _losingTokenInitialBalance,
                _playerSharePercentage,
                _stakerSharePercentage,
                _stakerContribution
            );

        _claimFunds(_winningToken, _claimedWinningToken);
        _claimFunds(_losingToken, _claimedLosingToken);
    }

    function deleteMatch(
        bytes32 poolA,
        bytes32 poolB,
        address foundsReceiver
    ) public onlyOwner {
        bytes32 matchId = getMatchId(poolA, poolB);
        require(!matches[matchId].isActive, "Match is active");

        _deletePool(poolA, foundsReceiver);
        _deletePool(poolB, foundsReceiver);
        _deleteMatch(matchId);
        _deleteMatchClaimRecord(matchId);
    }

    function setPoolDepositAllowed(
        bytes32 poolId,
        bool isDepositAllowed
    ) public onlyOwner {
        _setPoolDepositAllowed(poolId, isDepositAllowed);
    }

    function setPoolWithdrawalAllowed(
        bytes32 poolId,
        bool isWithdrawalAllowed
    ) public onlyOwner {
        _setPoolWithdrawalAllowed(poolId, isWithdrawalAllowed);
    }

    function endMatchAndClaimAndDelete(
        bytes32 poolA,
        bytes32 poolB,
        bytes32 winner,
        address[] memory players,
        uint256[] memory shares,
        address foundsReceiver
    ) public onlyOwner nonReentrant {
        // Step 1: End the match
        setPoolState(poolA, PoolState.MATCH_ENDED);
        setPoolState(poolB, PoolState.MATCH_ENDED);

        bytes32 matchId = getMatchId(poolA, poolB);
        super.endMatch(poolA, poolB, winner, players, shares);

        bytes32 _losingToken = getLoser(poolA, poolB);
        uint256 _losingTokenBalance = pools[_losingToken].totalFunds;

        uint256 _serviceFee = _claimServiceFee(
            matchId,
            pools[_losingToken].tokenAddress,
            _losingTokenBalance
        );
        _claimFunds(_losingToken, _serviceFee);

        // Step 2: Claim prizes for all eligible users
        _claimPrizesForAllUsers(matchId, poolA, poolB, winner, _losingToken, _losingTokenBalance, players);

        // Step 3: Delete the match and pools
        require(!matches[matchId].isActive, "Match is active");
        _deletePool(poolA, foundsReceiver);
        _deletePool(poolB, foundsReceiver);
        _deleteMatch(matchId);
        _deleteMatchClaimRecord(matchId);
    }

    function _claimPrizesForAllUsers(
        bytes32 matchId,
        bytes32 poolA,
        bytes32 poolB,
        bytes32 _winningToken,
        bytes32 _losingToken,
        uint256 _losingTokenInitialBalance,
        address[] memory players
    ) internal {
        // Claim for all stakers (contributors to winning pool)
        Pool storage winningPool = pools[_winningToken];
        for (uint256 i = 0; i < winningPool.contributors.length; i++) {
            address contributor = winningPool.contributors[i];
            if (pools[_winningToken].contributions[contributor] > 0) {
                _claimPrizeForAddress(
                    matchId,
                    poolA,
                    poolB,
                    _winningToken,
                    _losingToken,
                    _losingTokenInitialBalance,
                    contributor
                );
            }
        }

        // Claim for all players (if they haven't already claimed as stakers)
        for (uint256 i = 0; i < players.length; i++) {
            address player = players[i];
            uint256 playerShare = getPlayerShare(poolA, poolB, player);
            if (playerShare > 0 && !matchClaimRecords[matchId].hasClaimedPlayerPrize[player]) {
                _claimPlayerPrizeForAddress(
                    matchId,
                    poolA,
                    poolB,
                    _winningToken,
                    _losingToken,
                    _losingTokenInitialBalance,
                    player,
                    playerShare
                );
            }
        }
    }

    function _claimPrizeForAddress(
        bytes32 /* _matchId */,
        bytes32 poolA,
        bytes32 poolB,
        bytes32 _winningToken,
        bytes32 _losingToken,
        uint256 _losingTokenInitialBalance,
        address claimer
    ) internal {
        bytes32 matchIdCheck = getMatchId(poolA, poolB);
        require(
            !matchClaimRecords[matchIdCheck].hasClaimedStakerRefund[claimer],
            "Already claimed"
        );
        require(
            !matchClaimRecords[matchIdCheck].hasClaimedStakerPrize[claimer],
            "Already claimed"
        );

        matchClaimRecords[matchIdCheck].hasClaimedStakerRefund[claimer] = true;
        matchClaimRecords[matchIdCheck].hasClaimedStakerPrize[claimer] = true;

        uint256 _playerSharePercentage = getPlayerShare(poolA, poolB, claimer);
        if (_playerSharePercentage > 0) {
            matchClaimRecords[matchIdCheck].hasClaimedPlayerPrize[claimer] = true;
        }

        uint256 _stakerSharePercentage = getStakerShare(_winningToken, claimer);
        uint256 _stakerContribution = getContribution(_winningToken, claimer);

        uint256 claimableStakerPrize = _getClaimableStakerPrize(
            _losingTokenInitialBalance,
            _stakerSharePercentage
        );

        uint256 claimablePlayerPrize = 0;
        if (_playerSharePercentage > 0) {
            claimablePlayerPrize = _getClaimablePlayerPrize(
                _losingTokenInitialBalance,
                _playerSharePercentage
            );
        }

        // Transfer winning token (staker refund)
        if (pools[_winningToken].tokenAddress == address(0)) {
            (bool success, ) = payable(claimer).call{value: _stakerContribution}("");
            require(success, "Transfer failed");
        } else {
            IERC20 winningToken = IERC20(pools[_winningToken].tokenAddress);
            winningToken.safeTransfer(claimer, _stakerContribution);
        }

        // Transfer losing token (prizes)
        uint256 totalPrize = claimableStakerPrize + claimablePlayerPrize;
        if (totalPrize > 0) {
            if (pools[_losingToken].tokenAddress == address(0)) {
                (bool success, ) = payable(claimer).call{value: totalPrize}("");
                require(success, "Transfer failed");
            } else {
                IERC20 losingToken = IERC20(pools[_losingToken].tokenAddress);
                losingToken.safeTransfer(claimer, totalPrize);
            }
        }

        _claimFunds(_winningToken, _stakerContribution);
        _claimFunds(_losingToken, totalPrize);

        emit ClaimedStakePrice(claimer, pools[_winningToken].tokenAddress, _stakerContribution);
        if (claimableStakerPrize > 0) {
            emit ClaimedStakePrice(claimer, pools[_losingToken].tokenAddress, claimableStakerPrize);
        }
        if (claimablePlayerPrize > 0) {
            emit ClaimedPlayerPrice(claimer, pools[_losingToken].tokenAddress, claimablePlayerPrize);
        }
    }

    function _claimPlayerPrizeForAddress(
        bytes32 /* _matchId */,
        bytes32 poolA,
        bytes32 poolB,
        bytes32 /* _winningToken */,
        bytes32 _losingToken,
        uint256 _losingTokenInitialBalance,
        address player,
        uint256 playerShare
    ) internal {
        bytes32 matchIdCheck = getMatchId(poolA, poolB);
        require(
            !matchClaimRecords[matchIdCheck].hasClaimedPlayerPrize[player],
            "Already claimed"
        );

        matchClaimRecords[matchIdCheck].hasClaimedPlayerPrize[player] = true;

        uint256 claimablePlayerPrize = _getClaimablePlayerPrize(
            _losingTokenInitialBalance,
            playerShare
        );

        if (claimablePlayerPrize > 0) {
            if (pools[_losingToken].tokenAddress == address(0)) {
                (bool success, ) = payable(player).call{value: claimablePlayerPrize}("");
                require(success, "Transfer failed");
            } else {
                IERC20 losingToken = IERC20(pools[_losingToken].tokenAddress);
                losingToken.safeTransfer(player, claimablePlayerPrize);
            }

            _claimFunds(_losingToken, claimablePlayerPrize);
            emit ClaimedPlayerPrice(player, pools[_losingToken].tokenAddress, claimablePlayerPrize);
        }
    }
}
        

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Address.sol)

pragma solidity ^0.8.20;

import {Errors} from "./Errors.sol";

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert Errors.InsufficientBalance(address(this).balance, amount);
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert Errors.FailedCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {Errors.FailedCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {Errors.FailedCall}) in case
     * of an unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {Errors.FailedCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {Errors.FailedCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            assembly ("memory-safe") {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert Errors.FailedCall();
        }
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Errors.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of common custom errors used in multiple contracts
 *
 * IMPORTANT: Backwards compatibility is not guaranteed in future versions of the library.
 * It is recommended to avoid relying on the error API for critical functionality.
 *
 * _Available since v5.1._
 */
library Errors {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error InsufficientBalance(uint256 balance, uint256 needed);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedCall();

    /**
     * @dev The deployment failed.
     */
    error FailedDeployment();

    /**
     * @dev A necessary precompile is missing.
     */
    error MissingPrecompile(address);
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}
          

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

// This contract has the responsibility of managing the state of a match
// A match is between two pools
abstract contract MatchManager {
    enum MatchState {
        PRE_MATCH,
        MATCH_IN_PROGRESS,
        MATCH_ENDED
    }

    struct Match {
        bytes32 poolA;
        bytes32 poolB;
        bytes32 winner;
        uint256 totalFundsA;
        uint256 totalFundsB;
        bool isActive;
        MatchState state;
        mapping(address => uint256) playerShares;
    }

    mapping(bytes32 => Match) public matches;

    event MatchCreated(
        bytes32 indexed poolA,
        bytes32 indexed poolB,
        bytes32 indexed matchId
    );
    event MatchStarted(
        bytes32 indexed poolA,
        bytes32 indexed poolB,
        bytes32 indexed matchId
    );
    event MatchEnded(
        bytes32 indexed poolA,
        bytes32 indexed poolB,
        bytes32 indexed matchId
    );

    function _createMatch(
        bytes32 poolA,
        bytes32 poolB
    ) internal returns (bytes32) {
        require(poolA != poolB, "Pools must be different");
        require(poolA != bytes32(0), "Invalid pool A ID");
        require(poolB != bytes32(0), "Invalid pool B ID");
        bytes32 matchId = getMatchId(poolA, poolB);
        require(!matches[matchId].isActive, "Match already exists");

        Match storage newMatch = matches[matchId];
        newMatch.poolA = poolA;
        newMatch.poolB = poolB;
        newMatch.isActive = true;
        newMatch.state = MatchState.PRE_MATCH;

        emit MatchCreated(poolA, poolB, matchId);
        return matchId;
    }

    function _startMatch(bytes32 poolA, bytes32 poolB) internal {
        bytes32 matchId = getMatchId(poolA, poolB);
        require(matches[matchId].isActive, "Match does not exist");
        require(
            matches[matchId].state == MatchState.PRE_MATCH,
            "Match already started"
        );

        matches[matchId].state = MatchState.MATCH_IN_PROGRESS;

        emit MatchStarted(poolA, poolB, matchId);
    }

    function endMatch(
        bytes32 poolA,
        bytes32 poolB,
        bytes32 winner,
        address[] memory players,
        uint256[] memory shares
    ) public virtual {
        bytes32 matchId = getMatchId(poolA, poolB);
        require(matches[matchId].isActive, "Match does not exist");
        require(
            matches[matchId].state == MatchState.MATCH_IN_PROGRESS,
            "Match not in progress"
        );
        require(winner == poolA || winner == poolB, "Invalid winner address");

        require(players.length == shares.length, "Arrays length mismatch");
        require(players.length > 0, "No players provided");

        Match storage _match = matches[matchId];
        _match.winner = winner;
        _match.state = MatchState.MATCH_ENDED;
        _match.isActive = false;

        _setShares(matchId, players, shares);

        emit MatchEnded(poolA, poolB, matchId);
    }

    function _setShares(
        bytes32 _matchId,
        address[] memory _players,
        uint256[] memory _shares
    ) internal {
        require(_players.length == _shares.length, "Arrays length mismatch");
        require(_players.length > 0, "Empty arrays");

        Match storage _match = matches[_matchId];

        uint256 totalSharePercentage;
        for (uint256 i = 0; i < _players.length; i++) {
            require(_players[i] != address(0), "Invalid player address");
            require(_shares[i] > 0, "Invalid share percentage");
            totalSharePercentage += _shares[i];
            _match.playerShares[_players[i]] = _shares[i];
        }

        require(totalSharePercentage == 10000, "Total shares must be 100%");
    }

    function _deleteMatch(bytes32 matchId) internal {
        require(matchId != bytes32(0), "Invalid match ID");
        delete matches[matchId];
    }

    function getMatchId(
        bytes32 poolA,
        bytes32 poolB
    ) public pure returns (bytes32) {
        require(poolA != bytes32(0), "Invalid pool A ID");
        require(poolB != bytes32(0), "Invalid pool B ID");
        bytes32 pool1 = poolA < poolB ? poolA : poolB;
        bytes32 pool2 = poolA < poolB ? poolB : poolA;
        return keccak256(abi.encodePacked(pool1, pool2));
    }

    function getLoser(
        bytes32 poolA,
        bytes32 poolB
    ) public view returns (bytes32) {
        bytes32 matchId = getMatchId(poolA, poolB);
        Match storage _match = matches[matchId];
        return _match.winner == poolA ? poolB : poolA;
    }

    function getPlayerShare(
        bytes32 poolA,
        bytes32 poolB,
        address player
    ) public view returns (uint256) {
        bytes32 matchId = getMatchId(poolA, poolB);
        Match storage _match = matches[matchId];
        return _match.playerShares[player];
    }
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";

abstract contract PoolManager is Ownable, ReentrancyGuard {
    enum PoolState {
        PRE_MATCH,
        MATCH_IN_PROGRESS,
        MATCH_ENDED
    }

    struct Pool {
        address creator;
        address tokenAddress;
        uint256 totalFunds;
        uint256 remainingFunds;
        bool isActive;
        PoolState state;
        mapping(address => uint256) contributions;
        address[] contributors;
        bytes32 matchId;
        bool isDepositAllowed;
        bool isWithdrawalAllowed;
    }

    mapping(bytes32 => Pool) public pools;
    bytes32[] public allPoolIds;

    event PoolCreated(
        bytes32 indexed poolId,
        address indexed tokenAddress,
        address indexed creator
    );
    event FundsDeposited(
        bytes32 indexed poolId,
        address indexed tokenAddress,
        address indexed depositor,
        uint256 amount
    );
    event FundsWithdrawn(
        bytes32 indexed poolId,
        address indexed tokenAddress,
        address indexed withdrawer,
        uint256 amount
    );

    function _createPool(
        bytes32 poolId,
        address tokenAddress
    ) internal returns (address) {
        require(!pools[poolId].isActive, "Pool already exists");

        // Check if it's a ERC20 token
        if (tokenAddress != address(0)) {
            IERC20 token = IERC20(tokenAddress);
            require(token.totalSupply() > 0, "Invalid token address");
        }

        Pool storage newPool = pools[poolId];
        newPool.creator = msg.sender;
        newPool.tokenAddress = tokenAddress;
        newPool.isActive = true;
        newPool.state = PoolState.PRE_MATCH;
        newPool.isDepositAllowed = true;
        newPool.isWithdrawalAllowed = true;

        allPoolIds.push(poolId);

        emit PoolCreated(poolId, tokenAddress, msg.sender);
        return tokenAddress;
    }

    function _matchPools(
        bytes32 _poolA,
        bytes32 _poolB,
        bytes32 _matchId
    ) internal {
        Pool storage poolA = pools[_poolA];
        Pool storage poolB = pools[_poolB];
        poolA.matchId = _matchId;
        poolB.matchId = _matchId;

        poolA.state = PoolState.MATCH_IN_PROGRESS;
        poolB.state = PoolState.MATCH_IN_PROGRESS;
    }

    function setPoolState(bytes32 poolId, PoolState newState) public virtual {
        require(pools[poolId].isActive, "Pool does not exist");
        pools[poolId].state = newState;

        if (newState == PoolState.MATCH_ENDED) {
            pools[poolId].remainingFunds = pools[poolId].totalFunds;
        }
    }

    function _claimFunds(bytes32 poolId, uint256 amount) internal {
        pools[poolId].remainingFunds -= amount;
    }

    function depositToPool(
        bytes32 poolId,
        uint256 amount
    ) public payable nonReentrant {
        Pool storage pool = pools[poolId];
        require(pool.isActive, "Pool does not exist");
        require(pool.isDepositAllowed, "Deposits are not allowed");

        if (pool.tokenAddress == address(0)) {
            require(msg.value == amount, "Must send some tokens");
        } else {
            require(amount > 0, "Must send some tokens");
            IERC20 token = IERC20(pool.tokenAddress);
            require(
                token.transferFrom(msg.sender, address(this), amount),
                "Transfer failed"
            );
        }

        pool.totalFunds += amount;
        pool.contributions[msg.sender] += amount;
        pool.contributors.push(msg.sender);

        emit FundsDeposited(poolId, pool.tokenAddress, msg.sender, amount);
    }

    function withdrawFromPool(
        bytes32 poolId,
        uint256 amount
    ) public nonReentrant {
        Pool storage pool = pools[poolId];
        require(pool.isActive, "Pool is not active");
        require(pool.isWithdrawalAllowed, "Withdrawals are not allowed");
        require(amount > 0, "Must withdraw some tokens");
        require(pool.contributions[msg.sender] >= amount, "Insufficient funds");

        pool.totalFunds -= amount;
        pool.contributions[msg.sender] -= amount;

        if (pool.tokenAddress == address(0)) {
            (bool success, ) = payable(msg.sender).call{value: amount}("");
            require(success, "Transfer failed");
        } else {
            IERC20 token = IERC20(pool.tokenAddress);
            require(token.transfer(msg.sender, amount), "Transfer failed");
        }

        emit FundsWithdrawn(poolId, pool.tokenAddress, msg.sender, amount);
    }

    function getPoolBalance(bytes32 poolId) public view returns (uint256) {
        return pools[poolId].totalFunds;
    }

    function getPoolRemainingFunds(
        bytes32 poolId
    ) public view returns (uint256) {
        return pools[poolId].remainingFunds;
    }

    function getContribution(
        bytes32 poolId,
        address contributor
    ) public view returns (uint256) {
        return pools[poolId].contributions[contributor];
    }

    function getStakerShare(
        bytes32 poolId,
        address contributor
    ) public view returns (uint256) {
        if (pools[poolId].totalFunds == 0) {
            return 0;
        }
        return
            (pools[poolId].contributions[contributor] * 10000) /
            pools[poolId].totalFunds;
    }

    function getPoolMatchId(bytes32 poolId) public view returns (bytes32) {
        return pools[poolId].matchId;
    }

    function getPoolContributors(
        bytes32 poolId,
        uint256 _page,
        uint256 _pageSize
    ) public view returns (address[] memory) {
        Pool storage pool = pools[poolId];
        uint256 start = _page * _pageSize;
        uint256 end = start + _pageSize;
        if (end > pool.contributors.length) {
            end = pool.contributors.length;
        }
        address[] memory contributors = new address[](end - start);
        for (uint256 i = start; i < end; i++) {
            contributors[i - start] = pool.contributors[i];
        }
        return contributors;
    }

    function _deletePool(bytes32 poolId, address foundsReceiver) internal {
        uint256 remainingFunds = pools[poolId].remainingFunds;
        if (pools[poolId].tokenAddress == address(0)) {
            (bool success, ) = payable(foundsReceiver).call{
                value: remainingFunds
            }("");
            require(success, "Transfer failed");
        } else {
            // Withdraw the remaining funds
            IERC20 token = IERC20(pools[poolId].tokenAddress);
            require(
                token.transfer(payable(foundsReceiver), remainingFunds),
                "Transfer failed"
            );
        }

        delete pools[poolId];
    }

    function _setPoolDepositAllowed(
        bytes32 poolId,
        bool isDepositAllowed
    ) public {
        require(pools[poolId].isActive, "Pool does not exist");
        pools[poolId].isDepositAllowed = isDepositAllowed;
    }

    function _setPoolWithdrawalAllowed(
        bytes32 poolId,
        bool isWithdrawalAllowed
    ) public {
        require(pools[poolId].isActive, "Pool does not exist");
        pools[poolId].isWithdrawalAllowed = isWithdrawalAllowed;
    }

    function isPoolDepositAllowed(bytes32 poolId) public view returns (bool) {
        return pools[poolId].isDepositAllowed;
    }

    function isPoolWithdrawalAllowed(
        bytes32 poolId
    ) public view returns (bool) {
        return pools[poolId].isWithdrawalAllowed;
    }

    struct PoolInfo {
        bytes32 poolId;
        address tokenAddress;
        uint256 totalFunds;
        uint256 remainingFunds;
        bool isActive;
        PoolState state;
        bool isDepositAllowed;
        bool isWithdrawalAllowed;
        bytes32 matchId;
    }

    function getAllPools() public view returns (PoolInfo[] memory) {
        uint256 poolCount = allPoolIds.length;
        PoolInfo[] memory poolInfos = new PoolInfo[](poolCount);

        for (uint256 i = 0; i < poolCount; i++) {
            bytes32 poolId = allPoolIds[i];
            Pool storage pool = pools[poolId];
            
            poolInfos[i] = PoolInfo({
                poolId: poolId,
                tokenAddress: pool.tokenAddress,
                totalFunds: pool.totalFunds,
                remainingFunds: pool.remainingFunds,
                isActive: pool.isActive,
                state: pool.state,
                isDepositAllowed: pool.isDepositAllowed,
                isWithdrawalAllowed: pool.isWithdrawalAllowed,
                matchId: pool.matchId
            });
        }

        return poolInfos;
    }

    function getPoolsCount() public view returns (uint256) {
        return allPoolIds.length;
    }
}
          

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

abstract contract PrizeManager is ReentrancyGuard {
    struct ClaimRecord {
        bool isServiceFeeClaimed;
        mapping(address => bool) hasClaimedStakerRefund;
        mapping(address => bool) hasClaimedStakerPrize;
        mapping(address => bool) hasClaimedPlayerPrize;
    }

    uint256 public serviceFeePercentage = 1000; //10%
    uint256 public stakersPrizePercentage = 8100; //81%
    uint256 public playersPrizePercentage = 900; //9%
    uint256 private TOT = 10000; //100%

    mapping(bytes32 => ClaimRecord) public matchClaimRecords;

    event ClaimedServiceFee(
        address indexed receiver,
        address indexed token,
        uint256 amount
    );

    event ClaimedStakePrice(
        address indexed player,
        address indexed token,
        uint256 amount
    );
    event ClaimedPlayerPrice(
        address indexed player,
        address indexed token,
        uint256 amount
    );

    function _claimServiceFee(
        bytes32 _matchId,
        address _losingToken,
        uint256 _losingTokenBalance
    ) internal nonReentrant returns (uint256) {
        require(
            matchClaimRecords[_matchId].isServiceFeeClaimed == false,
            "Already claimed"
        );
        matchClaimRecords[_matchId].isServiceFeeClaimed = true;

        uint256 totalBalance = _losingTokenBalance;
        uint256 feeAmount = (totalBalance * serviceFeePercentage) / TOT;

        if (_losingToken == address(0)) {
            (bool success, ) = msg.sender.call{value: feeAmount}("");
            require(success, "Transfer failed");
        } else {
            IERC20 token = IERC20(_losingToken);
            token.transfer(msg.sender, feeAmount);
        }

        emit ClaimedServiceFee(msg.sender, _losingToken, feeAmount);

        return feeAmount;
    }

    function _claimPrize(
        bytes32 _matchId,
        address _winningToken,
        address _losingToken,
        uint256 _losingTokenInitialBalance,
        uint256 _playerSharePercentage,
        uint256 _stakerSharePercentage,
        uint256 _stakerContribution
    )
        internal
        returns (uint256 _claimableWinningToken, uint256 _claimableLosingToken)
    {
        require(
            matchClaimRecords[_matchId].hasClaimedStakerRefund[msg.sender] ==
                false,
            "Already claimed"
        );
        require(
            matchClaimRecords[_matchId].hasClaimedStakerPrize[msg.sender] ==
                false,
            "Already claimed"
        );
        require(
            matchClaimRecords[_matchId].hasClaimedPlayerPrize[msg.sender] ==
                false,
            "Already claimed"
        );

        matchClaimRecords[_matchId].hasClaimedStakerRefund[msg.sender] = true;
        matchClaimRecords[_matchId].hasClaimedStakerPrize[msg.sender] = true;
        matchClaimRecords[_matchId].hasClaimedPlayerPrize[msg.sender] = true;

        uint256 claimableStakerPrize = _getClaimableStakerPrize(
            _losingTokenInitialBalance,
            _stakerSharePercentage
        );

        uint256 claimablePlayerPrize = _getClaimablePlayerPrize(
            _losingTokenInitialBalance,
            _playerSharePercentage
        );

        if (_winningToken == address(0)) {
            (bool success, ) = msg.sender.call{value: _stakerContribution}("");
            require(success, "Transfer failed");
        } else {
            IERC20 winningToken = IERC20(_winningToken);
            winningToken.transfer(msg.sender, _stakerContribution);
        }

        if (_losingToken == address(0)) {
            (bool success, ) = msg.sender.call{
                value: claimableStakerPrize + claimablePlayerPrize
            }("");
            require(success, "Transfer failed");
        } else {
            IERC20 losingToken = IERC20(_losingToken);

            losingToken.transfer(
                msg.sender,
                claimableStakerPrize + claimablePlayerPrize
            );
        }

        emit ClaimedStakePrice(msg.sender, _winningToken, _stakerContribution);
        emit ClaimedStakePrice(msg.sender, _losingToken, claimableStakerPrize);
        emit ClaimedPlayerPrice(msg.sender, _losingToken, claimablePlayerPrize);

        return (
            _stakerContribution,
            claimableStakerPrize + claimablePlayerPrize
        );
    }

    function _getClaimableStakerRefund(
        uint256 winningTokenInitialBalance,
        uint256 sharePercentage
    ) internal view returns (uint256) {
        uint256 stakerRefund = (winningTokenInitialBalance * sharePercentage) /
            TOT;
        return stakerRefund;
    }

    function _getClaimableStakerPrize(
        uint256 losingTokenInitialBalance,
        uint256 sharePercentage
    ) internal view returns (uint256) {
        // Calculate stakers price (81%)
        uint256 totalStakersPrize = (losingTokenInitialBalance *
            stakersPrizePercentage);

        // Calculate player share of stakers price
        uint256 playerPrize = (totalStakersPrize * sharePercentage) /
            (TOT * TOT);

        return playerPrize;
    }

    function _getClaimablePlayerPrize(
        uint256 losingTokenInitialBalance,
        uint256 sharePercentage
    ) internal view returns (uint256) {
        // Calculate player amount (9%)
        uint256 totalPlayersPrize = (losingTokenInitialBalance *
            playersPrizePercentage);

        // Calculate player share of players prize
        uint256 playerPrize = (totalPlayersPrize * sharePercentage) /
            (TOT * TOT);

        return playerPrize;
    }

    function _deleteMatchClaimRecord(bytes32 _matchId) internal {
        delete matchClaimRecords[_matchId];
    }
}